Gecko [ paroquia-rio-de-mouro.pt ]

Name	Size	Permission	Date
Carp	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Exporter	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
File	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Getopt	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Hash	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
IO	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
IPC	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
List	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Scalar	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Text	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
Tie	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
auto	[ DIR ]	drwxr-xr-x	2016-03-13 12:54
unicore	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
warnings	[ DIR ]	drwxr-xr-x	2020-10-27 07:29
AutoLoader.pm	5.36 KB	-rw-r--r--	2020-10-19 12:57
Carp.pm	19.6 KB	-rw-r--r--	2020-10-19 12:57
Config.pm	3.25 KB	-rw-r--r--	2020-10-19 12:57
Config_git.pl	409 B	-rw-r--r--	2020-10-19 12:57
Config_heavy.pl	48.62 KB	-rw-r--r--	2020-10-19 12:57
Cwd.pm	18.27 KB	-rw-r--r--	2020-10-19 12:57
DynaLoader.pm	10.5 KB	-rw-r--r--	2020-10-19 12:57
Errno.pm	4.77 KB	-rw-r--r--	2020-10-19 12:57
Exporter.pm	2.31 KB	-rw-r--r--	2020-10-19 12:57
Fcntl.pm	2.11 KB	-rw-r--r--	2020-10-19 12:57
FileHandle.pm	2.06 KB	-rw-r--r--	2020-10-19 12:57
IO.pm	413 B	-rw-r--r--	2020-10-19 12:57
POSIX.pm	17.58 KB	-rw-r--r--	2020-10-19 12:57
SelectSaver.pm	344 B	-rw-r--r--	2020-10-19 12:57
Socket.pm	13.15 KB	-rw-r--r--	2020-10-19 12:57
Symbol.pm	2.05 KB	-rw-r--r--	2020-10-19 12:57
XSLoader.pm	3.95 KB	-rw-r--r--	2020-10-19 12:57
attributes.pm	2.95 KB	-rw-r--r--	2020-10-19 12:57
base.pm	5.21 KB	-rw-r--r--	2020-10-19 12:57
bytes.pm	447 B	-rw-r--r--	2020-10-19 12:57
bytes_heavy.pl	758 B	-rw-r--r--	2020-10-19 12:57
constant.pm	5.6 KB	-rw-r--r--	2020-10-19 12:57
feature.pm	4.08 KB	-rw-r--r--	2020-10-19 12:57
fields.pm	4.87 KB	-rw-r--r--	2020-10-19 12:57
integer.pm	172 B	-rw-r--r--	2020-10-19 12:57
lib.pm	2.23 KB	-rw-r--r--	2020-10-19 12:57
locale.pm	2.81 KB	-rw-r--r--	2020-10-19 12:57
overload.pm	4.36 KB	-rw-r--r--	2020-10-19 12:57
overloading.pm	964 B	-rw-r--r--	2020-10-19 12:57
parent.pm	607 B	-rw-r--r--	2020-10-19 12:57
re.pm	8.44 KB	-rw-r--r--	2020-10-19 12:57
strict.pm	1.48 KB	-rw-r--r--	2020-10-19 12:57
utf8.pm	342 B	-rw-r--r--	2020-10-19 12:57
utf8_heavy.pl	31.25 KB	-rw-r--r--	2020-10-19 12:57
vars.pm	1.12 KB	-rw-r--r--	2020-10-19 12:57
warnings.pm	21.49 KB	-rw-r--r--	2020-10-19 12:57

Rename

package fields;

require 5.005;
use strict;
no strict 'refs';
unless( eval q{require warnings::register; warnings::register->import; 1} ) {
    *warnings::warnif = sub { 
        require Carp;
        Carp::carp(@_);
    }
}
use vars qw(%attr $VERSION);

$VERSION = '2.17';

# constant.pm is slow
sub PUBLIC     () { 2**0  }
sub PRIVATE    () { 2**1  }
sub INHERITED  () { 2**2  }
sub PROTECTED  () { 2**3  }

# The %attr hash holds the attributes of the currently assigned fields
# per class.  The hash is indexed by class names and the hash value is
# an array reference.  The first element in the array is the lowest field
# number not belonging to a base class.  The remaining elements' indices
# are the field numbers.  The values are integer bit masks, or undef
# in the case of base class private fields (which occupy a slot but are
# otherwise irrelevant to the class).

sub import {
    my $class = shift;
    return unless @_;
    my $package = caller(0);
    # avoid possible typo warnings
    %{"$package\::FIELDS"} = () unless %{"$package\::FIELDS"};
    my $fields = \%{"$package\::FIELDS"};
    my $fattr = ($attr{$package} ||= [1]);
    my $next = @$fattr;

# Quiet pseudo-hash deprecation warning for uses of fields::new.
    bless \%{"$package\::FIELDS"}, 'pseudohash';

if ($next > $fattr->[0]
        and ($fields->{$_[0]} || 0) >= $fattr->[0])
    {
        # There are already fields not belonging to base classes.
        # Looks like a possible module reload...
        $next = $fattr->[0];
    }
    foreach my $f (@_) {
        my $fno = $fields->{$f};

# Allow the module to be reloaded so long as field positions
        # have not changed.
        if ($fno and $fno != $next) {
            require Carp;
            if ($fno < $fattr->[0]) {
              if ($] < 5.006001) {
                warn("Hides field '$f' in base class") if $^W;
              } else {
                warnings::warnif("Hides field '$f' in base class") ;
              }
            } else {
                Carp::croak("Field name '$f' already in use");
            }
        }
        $fields->{$f} = $next;
        $fattr->[$next] = ($f =~ /^_/) ? PRIVATE : PUBLIC;
        $next += 1;
    }
    if (@$fattr > $next) {
        # Well, we gave them the benefit of the doubt by guessing the
        # module was reloaded, but they appear to be declaring fields
        # in more than one place.  We can't be sure (without some extra
        # bookkeeping) that the rest of the fields will be declared or
        # have the same positions, so punt.
        require Carp;
        Carp::croak ("Reloaded module must declare all fields at once");
    }
}

sub inherit {
    require base;
    goto &base::inherit_fields;
}

sub _dump  # sometimes useful for debugging
{
    for my $pkg (sort keys %attr) {
        print "\n$pkg";
        if (@{"$pkg\::ISA"}) {
            print " (", join(", ", @{"$pkg\::ISA"}), ")";
        }
        print "\n";
        my $fields = \%{"$pkg\::FIELDS"};
        for my $f (sort {$fields->{$a} <=> $fields->{$b}} keys %$fields) {
            my $no = $fields->{$f};
            print "   $no: $f";
            my $fattr = $attr{$pkg}[$no];
            if (defined $fattr) {
                my @a;
                push(@a, "public")    if $fattr & PUBLIC;
                push(@a, "private")   if $fattr & PRIVATE;
                push(@a, "inherited") if $fattr & INHERITED;
                print "\t(", join(", ", @a), ")";
            }
            print "\n";
        }
    }
}

if ($] < 5.009) {
  *new = sub {
    my $class = shift;
    $class = ref $class if ref $class;
    return bless [\%{$class . "::FIELDS"}], $class;
  }
} else {
  *new = sub {
    my $class = shift;
    $class = ref $class if ref $class;
    require Hash::Util;
    my $self = bless {}, $class;

# The lock_keys() prototype won't work since we require Hash::Util :(
    &Hash::Util::lock_keys(\%$self, _accessible_keys($class));
    return $self;
  }
}

sub _accessible_keys {
    my ($class) = @_;
    return (
        keys %{$class.'::FIELDS'},
        map(_accessible_keys($_), @{$class.'::ISA'}),
    );
}

sub phash {
    die "Pseudo-hashes have been removed from Perl" if $] >= 5.009;
    my $h;
    my $v;
    if (@_) {
       if (ref $_[0] eq 'ARRAY') {
           my $a = shift;
           @$h{@$a} = 1 .. @$a;
           if (@_) {
               $v = shift;
               unless (! @_ and ref $v eq 'ARRAY') {
                   require Carp;
                   Carp::croak ("Expected at most two array refs\n");
               }
           }
       }
       else {
           if (@_ % 2) {
               require Carp;
               Carp::croak ("Odd number of elements initializing pseudo-hash\n");
           }
           my $i = 0;
           @$h{grep ++$i % 2, @_} = 1 .. @_ / 2;
           $i = 0;
           $v = [grep $i++ % 2, @_];
       }
    }
    else {
       $h = {};
       $v = [];
    }
    [ $h, @$v ];

}

__END__