Gecko [ paroquia-rio-de-mouro.pt ]

Name	Size	Permission	Date
Changelog	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Compression	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Control	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Dist	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Interface	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Shlibs	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Source	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Vendor	[ DIR ]	drwxr-xr-x	2021-12-04 13:17
Arch.pm	11.79 KB	-rw-r--r--	2021-04-20 22:48
BuildEnv.pm	2.2 KB	-rw-r--r--	2021-04-20 22:48
BuildFlags.pm	11.59 KB	-rw-r--r--	2021-04-20 22:48
BuildOptions.pm	4.93 KB	-rw-r--r--	2021-04-20 22:48
BuildProfiles.pm	3.41 KB	-rw-r--r--	2021-04-20 22:48
Changelog.pm	18.3 KB	-rw-r--r--	2021-04-20 22:48
Checksums.pm	10.4 KB	-rw-r--r--	2021-04-20 22:48
Compression.pm	6.25 KB	-rw-r--r--	2021-04-20 22:48
Conf.pm	4.21 KB	-rw-r--r--	2021-04-20 22:48
Control.pm	5.56 KB	-rw-r--r--	2021-04-20 22:48
Deps.pm	39.93 KB	-rw-r--r--	2021-04-20 22:48
ErrorHandling.pm	2.3 KB	-rw-r--r--	2021-04-20 22:48
Exit.pm	2.06 KB	-rw-r--r--	2021-04-20 22:48
File.pm	1.79 KB	-rw-r--r--	2021-04-20 22:48
Getopt.pm	1.08 KB	-rw-r--r--	2021-04-20 22:48
Gettext.pm	4.95 KB	-rw-r--r--	2021-04-20 22:48
IPC.pm	11.65 KB	-rw-r--r--	2021-04-20 22:48
Index.pm	8.6 KB	-rw-r--r--	2021-04-20 22:48
Package.pm	1.26 KB	-rw-r--r--	2021-04-20 22:48
Path.pm	7.48 KB	-rw-r--r--	2021-04-20 22:48
Shlibs.pm	4.43 KB	-rw-r--r--	2021-04-20 22:48
Substvars.pm	9.56 KB	-rw-r--r--	2021-04-20 22:48
Util.pm	1.41 KB	-rw-r--r--	2021-04-20 22:48
Vars.pm	1.42 KB	-rw-r--r--	2021-04-20 22:48
Vendor.pm	5.08 KB	-rw-r--r--	2021-04-20 22:48
Version.pm	11.55 KB	-rw-r--r--	2021-04-20 22:48

Rename

# Copyright © 2009-2010 Raphaël Hertzog <hertzog@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

package Dpkg::Conf;

use strict;
use warnings;

our $VERSION = '1.01';

use Dpkg::Gettext;
use Dpkg::ErrorHandling;

use parent qw(Dpkg::Interface::Storable);

use overload
    '@{}' => sub { return [ $_[0]->get_options() ] },
    fallback => 1;

=encoding utf8

=head1 NAME

Dpkg::Conf - parse dpkg configuration files

=head1 DESCRIPTION

The Dpkg::Conf object can be used to read options from a configuration
file. It can exports an array that can then be parsed exactly like @ARGV.

=head1 METHODS

=over 4

=item $conf = Dpkg::Conf->new(%opts)

Create a new Dpkg::Conf object. Some options can be set through %opts:
if allow_short evaluates to true (it defaults to false), then short
options are allowed in the configuration file, they should be prepended
with a single hyphen.

=cut

sub new {
    my ($this, %opts) = @_;
    my $class = ref($this) || $this;

my $self = {
	options => [],
	allow_short => 0,
    };
    foreach my $opt (keys %opts) {
	$self->{$opt} = $opts{$opt};
    }
    bless $self, $class;

return $self;
}

=item @$conf

=item @options = $conf->get_options()

Returns the list of options that can be parsed like @ARGV.

=cut

sub get_options {
    my $self = shift;
    return @{$self->{options}};
}

=item $conf->load($file)

Read options from a file. Return the number of options parsed.

=item $conf->parse($fh)

Parse options from a file handle. Return the number of options parsed.

=cut

sub parse {
    my ($self, $fh, $desc) = @_;
    my $count = 0;
    local $_;

while (<$fh>) {
	chomp;
	s/^\s+//;             # Strip leading spaces
	s/\s+$//;             # Strip trailing spaces
	s/\s+=\s+/=/;         # Remove spaces around the first =
	s/\s+/=/ unless m/=/; # First spaces becomes = if no =
	# Skip empty lines and comments
	next if /^#/ or length == 0;
	if (/^-[^-]/ and not $self->{allow_short}) {
	    warning(g_('short option not allowed in %s, line %d'), $desc, $.);
	    next;
	}
	if (/^([^=]+)(?:=(.*))?$/) {
	    my ($name, $value) = ($1, $2);
	    $name = "--$name" unless $name =~ /^-/;
	    if (defined $value) {
		$value =~ s/^"(.*)"$/$1/ or $value =~ s/^'(.*)'$/$1/;
		push @{$self->{options}}, "$name=$value";
	    } else {
		push @{$self->{options}}, $name;
	    }
	    $count++;
	} else {
	    warning(g_('invalid syntax for option in %s, line %d'), $desc, $.);
	}
    }
    return $count;
}

=item $conf->filter(remove => $rmfunc)

=item $conf->filter(keep => $keepfunc)

Filter the list of options, either removing or keeping all those that
return true when &$rmfunc($option) or &keepfunc($option) is called.

=cut

sub filter {
    my ($self, %opts) = @_;
    my $remove = $opts{remove} // sub { 0 };
    my $keep = $opts{keep} // sub { 1 };

@{$self->{options}} = grep { not &$remove($_) and &$keep($_) }
                               @{$self->{options}};
}

=item $string = $conf->output($fh)

Write the options in the given filehandle (if defined) and return a string
representation of the content (that would be) written.

=item "$conf"

Return a string representation of the content.

=item $conf->save($file)

Save the options in a file.

=cut

sub output {
    my ($self, $fh) = @_;
    my $ret = '';
    foreach my $opt ($self->get_options()) {
	$opt =~ s/^--//;
	if ($opt =~ s/^([^=]+)=/$1 = "/) {
	    $opt .= '"';
	}
	$opt .= "\n";
	print { $fh } $opt if defined $fh;
	$ret .= $opt;
    }
    return $ret;
}

=back

=head1 CHANGES

=head2 Version 1.01 (dpkg 1.15.8)

New method: $conf->filter()

=head2 Version 1.00 (dpkg 1.15.6)

Mark the module as public.

=head1 AUTHOR

Raphaël Hertzog <hertzog@debian.org>.

=cut