Gecko [ paroquia-rio-de-mouro.pt ]

Name	Size	Permission	Date
README.txt	1.6 KB	-rw-r--r--	2020-10-14 14:58
aap.vim	265 B	-rw-r--r--	2020-10-14 14:58
ada.vim	10.88 KB	-rw-r--r--	2020-10-14 14:58
ant.vim	290 B	-rw-r--r--	2020-10-14 14:58
automake.vim	231 B	-rw-r--r--	2020-10-14 14:58
awk.vim	7.57 KB	-rw-r--r--	2020-10-14 14:58
bib.vim	346 B	-rw-r--r--	2020-10-14 14:58
bst.vim	1.87 KB	-rw-r--r--	2020-10-14 14:58
bzl.vim	2.66 KB	-rw-r--r--	2020-10-14 14:58
c.vim	325 B	-rw-r--r--	2020-10-14 14:58
cdl.vim	4.07 KB	-rw-r--r--	2020-10-14 14:58
ch.vim	470 B	-rw-r--r--	2020-10-14 14:58
chaiscript.vim	1.11 KB	-rw-r--r--	2020-10-14 14:58
changelog.vim	264 B	-rw-r--r--	2020-10-14 14:58
clojure.vim	8.27 KB	-rw-r--r--	2020-10-14 14:58
cmake.vim	2.69 KB	-rw-r--r--	2020-10-14 14:58
cobol.vim	8 KB	-rw-r--r--	2020-10-14 14:58
config.vim	2.12 KB	-rw-r--r--	2020-10-14 14:58
cpp.vim	329 B	-rw-r--r--	2020-10-14 14:58
cs.vim	327 B	-rw-r--r--	2020-10-14 14:58
css.vim	1.68 KB	-rw-r--r--	2020-10-14 14:58
cucumber.vim	2.56 KB	-rw-r--r--	2020-10-14 14:58
cuda.vim	305 B	-rw-r--r--	2020-10-14 14:58
d.vim	510 B	-rw-r--r--	2020-10-14 14:58
dictconf.vim	325 B	-rw-r--r--	2020-10-14 14:58
dictdconf.vim	326 B	-rw-r--r--	2020-10-14 14:58
docbk.vim	324 B	-rw-r--r--	2020-10-14 14:58
dtd.vim	11.39 KB	-rw-r--r--	2020-10-14 14:58
dtrace.vim	451 B	-rw-r--r--	2020-10-14 14:58
dylan.vim	2.6 KB	-rw-r--r--	2020-10-14 14:58
eiffel.vim	3.13 KB	-rw-r--r--	2020-10-14 14:58
erlang.vim	45.15 KB	-rw-r--r--	2020-10-14 14:58
eruby.vim	2.11 KB	-rw-r--r--	2020-10-14 14:58
eterm.vim	638 B	-rw-r--r--	2020-10-14 14:58
falcon.vim	13.65 KB	-rw-r--r--	2020-10-14 14:58
fortran.vim	7.2 KB	-rw-r--r--	2020-10-14 14:58
framescript.vim	786 B	-rw-r--r--	2020-10-14 14:58
gitconfig.vim	817 B	-rw-r--r--	2020-10-14 14:58
gitolite.vim	996 B	-rw-r--r--	2020-10-14 14:58
go.vim	1.84 KB	-rw-r--r--	2020-10-14 14:58
haml.vim	2.14 KB	-rw-r--r--	2020-10-14 14:58
hamster.vim	1.37 KB	-rw-r--r--	2020-10-14 14:58
hog.vim	1.82 KB	-rw-r--r--	2020-10-14 14:58
html.vim	32.32 KB	-rw-r--r--	2020-10-14 14:58
htmldjango.vim	273 B	-rw-r--r--	2020-10-14 14:58
idlang.vim	1.53 KB	-rw-r--r--	2020-10-14 14:58
ishd.vim	1.8 KB	-rw-r--r--	2020-10-14 14:58
j.vim	1.77 KB	-rw-r--r--	2020-10-14 14:58
java.vim	4.02 KB	-rw-r--r--	2020-10-14 14:58
javascript.vim	377 B	-rw-r--r--	2020-10-14 14:58
json.vim	4.3 KB	-rw-r--r--	2020-10-14 14:58
jsp.vim	462 B	-rw-r--r--	2020-10-14 14:58
ld.vim	1.71 KB	-rw-r--r--	2020-10-14 14:58
less.vim	243 B	-rw-r--r--	2020-10-14 14:58
lifelines.vim	637 B	-rw-r--r--	2020-10-14 14:58
liquid.vim	1.83 KB	-rw-r--r--	2020-10-14 14:58
lisp.vim	353 B	-rw-r--r--	2020-10-14 14:58
logtalk.vim	1.65 KB	-rw-r--r--	2020-10-14 14:58
lua.vim	1.88 KB	-rw-r--r--	2020-10-14 14:58
mail.vim	308 B	-rw-r--r--	2020-10-14 14:58
make.vim	3.35 KB	-rw-r--r--	2020-10-14 14:58
matlab.vim	1.88 KB	-rw-r--r--	2020-10-14 14:58
mma.vim	2.17 KB	-rw-r--r--	2020-10-14 14:58
mp.vim	6.37 KB	-rw-r--r--	2020-10-14 14:58
objc.vim	1.61 KB	-rw-r--r--	2020-10-14 14:58
ocaml.vim	8.9 KB	-rw-r--r--	2020-10-14 14:58
occam.vim	4.53 KB	-rw-r--r--	2020-10-14 14:58
pascal.vim	5.52 KB	-rw-r--r--	2020-10-14 14:58
perl.vim	5.67 KB	-rw-r--r--	2020-10-14 14:58
perl6.vim	3.42 KB	-rw-r--r--	2020-10-14 14:58
php.vim	21.06 KB	-rw-r--r--	2020-10-14 14:58
postscr.vim	1.58 KB	-rw-r--r--	2020-10-14 14:58
pov.vim	2.58 KB	-rw-r--r--	2020-10-14 14:58
prolog.vim	1.42 KB	-rw-r--r--	2020-10-14 14:58
pyrex.vim	326 B	-rw-r--r--	2020-10-14 14:58
python.vim	5.61 KB	-rw-r--r--	2020-10-14 14:58
r.vim	13.46 KB	-rw-r--r--	2020-10-14 14:58
readline.vim	681 B	-rw-r--r--	2020-10-14 14:58
rhelp.vim	2.76 KB	-rw-r--r--	2020-10-14 14:58
rmd.vim	1.17 KB	-rw-r--r--	2020-10-14 14:58
rnoweb.vim	900 B	-rw-r--r--	2020-10-14 14:58
rpl.vim	1.79 KB	-rw-r--r--	2020-10-14 14:58
rrst.vim	1.17 KB	-rw-r--r--	2020-10-14 14:58
rst.vim	1.35 KB	-rw-r--r--	2020-10-14 14:58
ruby.vim	17.13 KB	-rw-r--r--	2020-10-14 14:58
sass.vim	1018 B	-rw-r--r--	2020-10-14 14:58
scheme.vim	241 B	-rw-r--r--	2020-10-14 14:58
scss.vim	191 B	-rw-r--r--	2020-10-14 14:58
sdl.vim	2.7 KB	-rw-r--r--	2020-10-14 14:58
sh.vim	4.71 KB	-rw-r--r--	2020-10-14 14:58
sml.vim	6.27 KB	-rw-r--r--	2020-10-14 14:58
sql.vim	1.18 KB	-rw-r--r--	2020-10-14 14:58
sqlanywhere.vim	12.77 KB	-rw-r--r--	2020-10-14 14:58
systemd.vim	205 B	-rw-r--r--	2020-10-14 14:58
systemverilog.vim	8.37 KB	-rw-r--r--	2020-10-14 14:58
tcl.vim	1.56 KB	-rw-r--r--	2020-10-14 14:58
tcsh.vim	1.21 KB	-rw-r--r--	2020-10-14 14:58
teraterm.vim	1.55 KB	-rw-r--r--	2020-10-14 14:58
tex.vim	12.83 KB	-rw-r--r--	2020-10-14 14:58
tf.vim	1.46 KB	-rw-r--r--	2020-10-14 14:58
tilde.vim	994 B	-rw-r--r--	2020-10-14 14:58
treetop.vim	677 B	-rw-r--r--	2020-10-14 14:58
vb.vim	2 KB	-rw-r--r--	2020-10-14 14:58
verilog.vim	7.44 KB	-rw-r--r--	2020-10-14 14:58
vhdl.vim	13.48 KB	-rw-r--r--	2020-10-14 14:58
vim.vim	2.92 KB	-rw-r--r--	2020-10-14 14:58
vroom.vim	379 B	-rw-r--r--	2020-10-14 14:58
xf86conf.vim	679 B	-rw-r--r--	2020-10-14 14:58
xhtml.vim	269 B	-rw-r--r--	2020-10-14 14:58
xinetd.vim	1.17 KB	-rw-r--r--	2020-10-14 14:58
xml.vim	2.77 KB	-rw-r--r--	2020-10-14 14:58
xsd.vim	253 B	-rw-r--r--	2020-10-14 14:58
xslt.vim	297 B	-rw-r--r--	2020-10-14 14:58
yacc.vim	769 B	-rw-r--r--	2020-10-14 14:58
yaml.vim	4.21 KB	-rw-r--r--	2020-10-14 14:58
zimbu.vim	3.84 KB	-rw-r--r--	2020-10-14 14:58
zsh.vim	411 B	-rw-r--r--	2020-10-14 14:58

Rename

" Vim indent file
" Language:	Clojure
" Author:	Meikel Brandmeyer <mb@kotka.de>
" URL:		http://kotka.de/projects/clojure/vimclojure.html
"
" Maintainer:	Sung Pae <self@sungpae.com>
" URL:		https://github.com/guns/vim-clojure-static
" License:	Same as Vim
" Last Change:	27 March 2014

" TODO: Indenting after multibyte characters is broken:
"       (let [Δ (if foo
"                bar    ; Indent error
"                baz)])

if exists("b:did_indent")
	finish
endif
let b:did_indent = 1

let s:save_cpo = &cpo
set cpo&vim

let b:undo_indent = 'setlocal autoindent< smartindent< expandtab< softtabstop< shiftwidth< indentexpr< indentkeys<'

setlocal noautoindent nosmartindent
setlocal softtabstop=2 shiftwidth=2 expandtab
setlocal indentkeys=!,o,O

if exists("*searchpairpos")

if !exists('g:clojure_maxlines')
		let g:clojure_maxlines = 100
	endif

if !exists('g:clojure_fuzzy_indent')
		let g:clojure_fuzzy_indent = 1
	endif

if !exists('g:clojure_fuzzy_indent_patterns')
		let g:clojure_fuzzy_indent_patterns = ['^with', '^def', '^let']
	endif

if !exists('g:clojure_fuzzy_indent_blacklist')
		let g:clojure_fuzzy_indent_blacklist = ['-fn$', '\v^with-%(meta|out-str|loading-context)$']
	endif

if !exists('g:clojure_special_indent_words')
		let g:clojure_special_indent_words = 'deftype,defrecord,reify,proxy,extend-type,extend-protocol,letfn'
	endif

if !exists('g:clojure_align_multiline_strings')
		let g:clojure_align_multiline_strings = 0
	endif

if !exists('g:clojure_align_subforms')
		let g:clojure_align_subforms = 0
	endif

function! s:SynIdName()
		return synIDattr(synID(line("."), col("."), 0), "name")
	endfunction

function! s:CurrentChar()
		return getline('.')[col('.')-1]
	endfunction

function! s:CurrentWord()
		return getline('.')[col('.')-1 : searchpos('\v>', 'n', line('.'))[1]-2]
	endfunction

function! s:IsParen()
		return s:CurrentChar() =~# '\v[\[\]\{\}]' &&
		     \ s:SynIdName() !~? '\vstring|regex|comment|character'
	endfunction

" Returns 1 if string matches a pattern in 'patterns', which may be a
	" list of patterns, or a comma-delimited string of implicitly anchored
	" patterns.
	function! s:MatchesOne(patterns, string)
		let list = type(a:patterns) == type([])
			   \ ? a:patterns
			   \ : map(split(a:patterns, ','), '"^" . v:val . "$"')
		for pat in list
			if a:string =~# pat | return 1 | endif
		endfor
	endfunction

function! s:MatchPairs(open, close, stopat)
		" Stop only on vector and map [ resp. {. Ignore the ones in strings and
		" comments.
		if a:stopat == 0
			let stopat = max([line(".") - g:clojure_maxlines, 0])
		else
			let stopat = a:stopat
		endif

let pos = searchpairpos(a:open, '', a:close, 'bWn', "!s:IsParen()", stopat)
		return [pos[0], virtcol(pos)]
	endfunction

function! s:ClojureCheckForStringWorker()
		" Check whether there is the last character of the previous line is
		" highlighted as a string. If so, we check whether it's a ". In this
		" case we have to check also the previous character. The " might be the
		" closing one. In case the we are still in the string, we search for the
		" opening ". If this is not found we take the indent of the line.
		let nb = prevnonblank(v:lnum - 1)

if nb == 0
			return -1
		endif

call cursor(nb, 0)
		call cursor(0, col("$") - 1)
		if s:SynIdName() !~? "string"
			return -1
		endif

" This will not work for a " in the first column...
		if s:CurrentChar() == '"'
			call cursor(0, col("$") - 2)
			if s:SynIdName() !~? "string"
				return -1
			endif
			if s:CurrentChar() != '\\'
				return -1
			endif
			call cursor(0, col("$") - 1)
		endif

let p = searchpos('$^\|[^\\]$\zs"', 'bW')

if p != [0, 0]
			return p[1] - 1
		endif

return indent(".")
	endfunction

function! s:CheckForString()
		let pos = getpos('.')
		try
			let val = s:ClojureCheckForStringWorker()
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

function! s:StripNamespaceAndMacroChars(word)
		return substitute(a:word, "\\v%(.*/|[#'`~@^,]*)(.*)", '\1', '')
	endfunction

function! s:ClojureIsMethodSpecialCaseWorker(position)
		" Find the next enclosing form.
		call search('\S', 'Wb')

" Special case: we are at a '(('.
		if s:CurrentChar() == '('
			return 0
		endif
		call cursor(a:position)

let nextParen = s:MatchPairs('(', ')', 0)

" Special case: we are now at toplevel.
		if nextParen == [0, 0]
			return 0
		endif
		call cursor(nextParen)

call search('\S', 'W')
		let w = s:StripNamespaceAndMacroChars(s:CurrentWord())
		if g:clojure_special_indent_words =~# '\V\<' . w . '\>'
			return 1
		endif

return 0
	endfunction

function! s:IsMethodSpecialCase(position)
		let pos = getpos('.')
		try
			let val = s:ClojureIsMethodSpecialCaseWorker(a:position)
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

function! GetClojureIndent()
		" Get rid of special case.
		if line(".") == 1
			return 0
		endif

" We have to apply some heuristics here to figure out, whether to use
		" normal lisp indenting or not.
		let i = s:CheckForString()
		if i > -1
			return i + !!g:clojure_align_multiline_strings
		endif

call cursor(0, 1)

" Find the next enclosing [ or {. We can limit the second search
		" to the line, where the [ was found. If no [ was there this is
		" zero and we search for an enclosing {.
		let paren = s:MatchPairs('(', ')', 0)
		let bracket = s:MatchPairs('\[', '\]', paren[0])
		let curly = s:MatchPairs('{', '}', bracket[0])

" In case the curly brace is on a line later then the [ or - in
		" case they are on the same line - in a higher column, we take the
		" curly indent.
		if curly[0] > bracket[0] || curly[1] > bracket[1]
			if curly[0] > paren[0] || curly[1] > paren[1]
				return curly[1]
			endif
		endif

" If the curly was not chosen, we take the bracket indent - if
		" there was one.
		if bracket[0] > paren[0] || bracket[1] > paren[1]
			return bracket[1]
		endif

" There are neither { nor [ nor (, ie. we are at the toplevel.
		if paren == [0, 0]
			return 0
		endif

" Now we have to reimplement lispindent. This is surprisingly easy, as
		" soon as one has access to syntax items.
		"
		" - Check whether we are in a special position after a word in
		"   g:clojure_special_indent_words. These are special cases.
		" - Get the next keyword after the (.
		" - If its first character is also a (, we have another sexp and align
		"   one column to the right of the unmatched (.
		" - In case it is in lispwords, we indent the next line to the column of
		"   the ( + sw.
		" - If not, we check whether it is last word in the line. In that case
		"   we again use ( + sw for indent.
		" - In any other case we use the column of the end of the word + 2.
		call cursor(paren)

if s:IsMethodSpecialCase(paren)
			return paren[1] + &shiftwidth - 1
		endif

" In case we are at the last character, we use the paren position.
		if col("$") - 1 == paren[1]
			return paren[1]
		endif

" In case after the paren is a whitespace, we search for the next word.
		call cursor(0, col('.') + 1)
		if s:CurrentChar() == ' '
			call search('\v\S', 'W')
		endif

" If we moved to another line, there is no word after the (. We
		" use the ( position for indent.
		if line(".") > paren[0]
			return paren[1]
		endif

" We still have to check, whether the keyword starts with a (, [ or {.
		" In that case we use the ( position for indent.
		let w = s:CurrentWord()
		if stridx('([{', w[0]) > -1
			return paren[1]
		endif

" Test words without namespace qualifiers and leading reader macro
		" metacharacters.
		"
		" e.g. clojure.core/defn and #'defn should both indent like defn.
		let ww = s:StripNamespaceAndMacroChars(w)

if &lispwords =~# '\V\<' . ww . '\>'
			return paren[1] + &shiftwidth - 1
		endif

if g:clojure_fuzzy_indent
			\ && !s:MatchesOne(g:clojure_fuzzy_indent_blacklist, ww)
			\ && s:MatchesOne(g:clojure_fuzzy_indent_patterns, ww)
			return paren[1] + &shiftwidth - 1
		endif

call search('\v\_s', 'cW')
		call search('\v\S', 'W')
		if paren[0] < line(".")
			return paren[1] + (g:clojure_align_subforms ? 0 : &shiftwidth - 1)
		endif

call search('\v\S', 'bW')
		return virtcol(".") + 1
	endfunction

setlocal indentexpr=GetClojureIndent()

else

" In case we have searchpairpos not available we fall back to
	" normal lisp indenting.
	setlocal indentexpr=
	setlocal lisp
	let b:undo_indent .= '| setlocal lisp<'

endif

let &cpo = s:save_cpo
unlet! s:save_cpo

" vim:sts=8:sw=8:ts=8:noet