Gecko [ paroquia-rio-de-mouro.pt ]

Name	Size	Permission	Date
_bootctl	1.04 KB	-rw-r--r--	2021-04-02 17:50
_busctl	3 KB	-rw-r--r--	2021-04-02 17:50
_curl	10.83 KB	-rw-r--r--	2021-03-29 17:38
_hostnamectl	2.17 KB	-rw-r--r--	2021-04-02 17:50
_journalctl	4.76 KB	-rw-r--r--	2021-04-02 17:50
_localectl	3.46 KB	-rw-r--r--	2021-04-02 17:50
_loginctl	5.63 KB	-rw-r--r--	2021-04-02 17:50
_sd_hosts_or_user_at_host	79 B	-rw-r--r--	2021-04-02 17:50
_sd_outputmodes	202 B	-rw-r--r--	2021-04-02 17:50
_sd_unit_files	226 B	-rw-r--r--	2021-04-02 17:50
_snap	1.75 KB	-rw-r--r--	2021-02-02 09:21
_systemctl	14.39 KB	-rw-r--r--	2021-04-02 17:50
_systemd	3.71 KB	-rw-r--r--	2021-04-02 17:50
_systemd-analyze	2.34 KB	-rw-r--r--	2021-04-02 17:50
_systemd-delta	527 B	-rw-r--r--	2021-04-02 17:50
_systemd-inhibit	1 KB	-rw-r--r--	2021-04-02 17:50
_systemd-run	3.01 KB	-rw-r--r--	2021-04-02 17:50
_systemd-tmpfiles	699 B	-rw-r--r--	2021-04-02 17:50
_timedatectl	1.96 KB	-rw-r--r--	2021-04-02 17:50
_udevadm	5.82 KB	-rw-r--r--	2021-04-02 17:50

Rename

#compdef timedatectl

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'